Vim thesaurus and word processor

.vim/autoload/pathogen.vim

@@ -0,0 +1,264 @@
+" pathogen.vim - path option manipulation
+" Maintainer:   Tim Pope <http://tpo.pe/>
+" Version:      2.4
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `execute pathogen#infect()` to the top of your
+" .vimrc is the only other setup necessary.
+"
+" The API is documented inline below.
+
+if exists("g:loaded_pathogen") || &cp
+  finish
+endif
+let g:loaded_pathogen = 1
+
+" Point of entry for basic default usage.  Give a relative path to invoke
+" pathogen#interpose() or an absolute path to invoke pathogen#surround().
+" Curly braces are expanded with pathogen#expand(): "bundle/{}" finds all
+" subdirectories inside "bundle" inside all directories in the runtime path.
+" If no arguments are given, defaults "bundle/{}", and also "pack/{}/start/{}"
+" on versions of Vim without native package support.
+function! pathogen#infect(...) abort
+  if a:0
+    let paths = filter(reverse(copy(a:000)), 'type(v:val) == type("")')
+  else
+    let paths = ['bundle/{}', 'pack/{}/start/{}']
+  endif
+  if has('packages')
+    call filter(paths, 'v:val !~# "^pack/[^/]*/start/[^/]*$"')
+  endif
+  let static = '^\%([$~\\/]\|\w:[\\/]\)[^{}*]*$'
+  for path in filter(copy(paths), 'v:val =~# static')
+    call pathogen#surround(path)
+  endfor
+  for path in filter(copy(paths), 'v:val !~# static')
+    if path =~# '^\%([$~\\/]\|\w:[\\/]\)'
+      call pathogen#surround(path)
+    else
+      call pathogen#interpose(path)
+    endif
+  endfor
+  call pathogen#cycle_filetype()
+  if pathogen#is_disabled($MYVIMRC)
+    return 'finish'
+  endif
+  return ''
+endfunction
+
+" Split a path into a list.
+function! pathogen#split(path) abort
+  if type(a:path) == type([]) | return a:path | endif
+  if empty(a:path) | return [] | endif
+  let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+  return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction
+
+" Convert a list to a path.
+function! pathogen#join(...) abort
+  if type(a:1) == type(1) && a:1
+    let i = 1
+    let space = ' '
+  else
+    let i = 0
+    let space = ''
+  endif
+  let path = ""
+  while i < a:0
+    if type(a:000[i]) == type([])
+      let list = a:000[i]
+      let j = 0
+      while j < len(list)
+        let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+        let path .= ',' . escaped
+        let j += 1
+      endwhile
+    else
+      let path .= "," . a:000[i]
+    endif
+    let i += 1
+  endwhile
+  return substitute(path,'^,','','')
+endfunction
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort
+  return call('pathogen#join',[1] + a:000)
+endfunction
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() abort
+  if exists('g:did_load_filetypes')
+    filetype off
+    filetype on
+  endif
+endfunction
+
+" Check if a bundle is disabled.  A bundle is considered disabled if its
+" basename or full name is included in the list g:pathogen_blacklist or the
+" comma delimited environment variable $VIMBLACKLIST.
+function! pathogen#is_disabled(path) abort
+  if a:path =~# '\~$'
+    return 1
+  endif
+  let sep = pathogen#slash()
+  let blacklist = get(g:, 'pathogen_blacklist', get(g:, 'pathogen_disabled', [])) + pathogen#split($VIMBLACKLIST)
+  if !empty(blacklist)
+    call map(blacklist, 'substitute(v:val, "[\\/]$", "", "")')
+  endif
+  return index(blacklist, fnamemodify(a:path, ':t')) != -1 || index(blacklist, a:path) != -1
+endfunction
+
+" Prepend the given directory to the runtime path and append its corresponding
+" after directory.  Curly braces are expanded with pathogen#expand().
+function! pathogen#surround(path) abort
+  let sep = pathogen#slash()
+  let rtp = pathogen#split(&rtp)
+  let path = fnamemodify(a:path, ':s?[\\/]\=$??')
+  let before = filter(pathogen#expand(path), '!pathogen#is_disabled(v:val)')
+  let after = filter(reverse(pathogen#expand(path, sep.'after')), '!pathogen#is_disabled(v:val[0:-7])')
+  call filter(rtp, 'index(before + after, v:val) == -1')
+  let &rtp = pathogen#join(before, rtp, after)
+  return &rtp
+endfunction
+
+" For each directory in the runtime path, add a second entry with the given
+" argument appended.  Curly braces are expanded with pathogen#expand().
+function! pathogen#interpose(name) abort
+  let sep = pathogen#slash()
+  let name = a:name
+  if has_key(s:done_bundles, name)
+    return ""
+  endif
+  let s:done_bundles[name] = 1
+  let list = []
+  for dir in pathogen#split(&rtp)
+    if dir =~# '\<after$'
+      let list += reverse(filter(pathogen#expand(dir[0:-6].name, sep.'after'), '!pathogen#is_disabled(v:val[0:-7])')) + [dir]
+    else
+      let list += [dir] + filter(pathogen#expand(dir.sep.name), '!pathogen#is_disabled(v:val)')
+    endif
+  endfor
+  let &rtp = pathogen#join(pathogen#uniq(list))
+  return 1
+endfunction
+
+let s:done_bundles = {}
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() abort
+  let sep = pathogen#slash()
+  for glob in pathogen#split(&rtp)
+    for dir in map(split(glob(glob), "\n"), 'v:val.sep."/doc/".sep')
+      if (dir)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir) == 2 && !empty(split(glob(dir.'*.txt'))) && (!filereadable(dir.'tags') || filewritable(dir.'tags'))
+        silent! execute 'helptags' pathogen#fnameescape(dir)
+      endif
+    endfor
+  endfor
+endfunction
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Execute the given command.  This is basically a backdoor for --remote-expr.
+function! pathogen#execute(...) abort
+  for command in a:000
+    execute command
+  endfor
+  return ''
+endfunction
+
+" Section: Unofficial
+
+function! pathogen#is_absolute(path) abort
+  return a:path =~# (has('win32') ? '^\%([\\/]\|\w:\)[\\/]\|^[~$]' : '^[/~$]')
+endfunction
+
+" Given a string, returns all possible permutations of comma delimited braced
+" alternatives of that string.  pathogen#expand('/{a,b}/{c,d}') yields
+" ['/a/c', '/a/d', '/b/c', '/b/d'].  Empty braces are treated as a wildcard
+" and globbed.  Actual globs are preserved.
+function! pathogen#expand(pattern, ...) abort
+  let after = a:0 ? a:1 : ''
+  let pattern = substitute(a:pattern, '^[~$][^\/]*', '\=expand(submatch(0))', '')
+  if pattern =~# '{[^{}]\+}'
+    let [pre, pat, post] = split(substitute(pattern, '\(.\{-\}\){\([^{}]\+\)}\(.*\)', "\\1\001\\2\001\\3", ''), "\001", 1)
+    let found = map(split(pat, ',', 1), 'pre.v:val.post')
+    let results = []
+    for pattern in found
+      call extend(results, pathogen#expand(pattern))
+    endfor
+  elseif pattern =~# '{}'
+    let pat = matchstr(pattern, '^.*{}[^*]*\%($\|[\\/]\)')
+    let post = pattern[strlen(pat) : -1]
+    let results = map(split(glob(substitute(pat, '{}', '*', 'g')), "\n"), 'v:val.post')
+  else
+    let results = [pattern]
+  endif
+  let vf = pathogen#slash() . 'vimfiles'
+  call map(results, 'v:val =~# "\\*" ? v:val.after : isdirectory(v:val.vf.after) ? v:val.vf.after : isdirectory(v:val.after) ? v:val.after : ""')
+  return filter(results, '!empty(v:val)')
+endfunction
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#slash() abort
+  return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction
+
+function! pathogen#separator() abort
+  return pathogen#slash()
+endfunction
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort
+  let files = split(glob(a:pattern),"\n")
+  return map(files,'substitute(v:val,"[".pathogen#slash()."/]$","","")')
+endfunction
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort
+  return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort
+  let i = 0
+  let seen = {}
+  while i < len(a:list)
+    if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+      call remove(a:list,i)
+    elseif a:list[i] ==# ''
+      let i += 1
+      let empty = 1
+    else
+      let seen[a:list[i]] = 1
+      let i += 1
+    endif
+  endwhile
+  return a:list
+endfunction
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) abort
+  if exists('*fnameescape')
+    return fnameescape(a:string)
+  elseif a:string ==# '-'
+    return '\-'
+  else
+    return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+  endif
+endfunction
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) abort
+  let rtp = pathogen#join(1,pathogen#split(&rtp))
+  let file = findfile(a:file,rtp,a:count)
+  if file ==# ''
+    return ''
+  else
+    return fnamemodify(file,':p')
+  endif
+endfunction
+
+" vim:set et sw=2 foldmethod=expr foldexpr=getline(v\:lnum)=~'^\"\ Section\:'?'>1'\:getline(v\:lnum)=~#'^fu'?'a1'\:getline(v\:lnum)=~#'^endf'?'s1'\:'=':

.vim/bundle/Vundle.vim

@@ -0,0 +1 @@
+Subproject commit b255382d6242d7ea3877bf059d2934125e0c4d95

.vim/bundle/ctrlp.vim

@@ -0,0 +1 @@
+Subproject commit 585143acbe15f362852d78bd050baff3c12902d7

.vim/bundle/markdown-preview.vim

@@ -0,0 +1 @@
+Subproject commit 5bd6364b1c4178aba87a8bd250d1f4b2e3d2b3d5

.vim/bundle/nerdtree

@@ -0,0 +1 @@
+Subproject commit 343508e9fd981928f1e830c71c9d8b2a54edb7dd

.vim/bundle/oceanic-next

@@ -0,0 +1 @@
+Subproject commit 08158eec24cd154afd1623686aeb336fad580be7

.vim/bundle/syntastic

@@ -0,0 +1 @@
+Subproject commit f3766538720116f099a8b1517f76ae2f094afd20

.vim/bundle/tender.vim

@@ -0,0 +1 @@
+Subproject commit f93b2f373cc21826524c94fbd1f3b3a4c55173d2

.vim/bundle/thesaurus_query.vim

@@ -0,0 +1 @@
+Subproject commit 830a20ec77780ebfe8d2a7e8c740ca4abb079f89

.vim/bundle/vim-airline

@@ -0,0 +1 @@
+Subproject commit 2f2003be52a73931c9f02d97c9d2360b5f8ffbf0

.vim/bundle/vim-airline-themes

@@ -0,0 +1 @@
+Subproject commit 63b66df2851c0851df9e8018f62ed7208f3485de

.vim/bundle/vim-markdown-preview

@@ -0,0 +1 @@
+Subproject commit 9b3ec41fb6f0f49d9bb7ca81fa1c62a8a54b1214

.vim/bundle/vim-rspec

@@ -0,0 +1 @@
+Subproject commit 52a72592b6128f4ef1557bc6e2e3eb014d8b2d38

.vim/bundle/vim-smooth-scroll

@@ -0,0 +1 @@
+Subproject commit 0eae2367c70c3415b97869346af1b5e30c123dff

.vim/bundle/vim-surround

@@ -0,0 +1 @@
+Subproject commit f51a26d3710629d031806305b6c8727189cd1935

.vim/bundle/vim-system-copy

@@ -0,0 +1 @@
+Subproject commit 32a362e259c61b582e61c816c0b89a1b2bbf0f8c

.vim/bundle/vimtex

@@ -0,0 +1 @@
+Subproject commit 32d72e57cf31440752158a8a16bc5efa4d684a3a

.vim/bundle/wal.vim

@@ -0,0 +1 @@
+Subproject commit 10f228ce1e7947f62be412f916229131b7710239

.vim/colors/railscasts.vim

@@ -0,0 +1,148 @@
+"
+" Name:    railscasts.vim
+" URL:     https://github.com/jpo/vim-railscasts-theme
+" License: MIT <http://opensource.org/licenses/MIT>
+"
+
+set background=dark
+hi clear
+if exists("syntax_on")
+  syntax reset
+endif
+let g:colors_name = "railscasts"
+
+hi Normal                    guifg=#e4e4e4 guibg=#121212 ctermfg=254 ctermbg=233
+hi Search                    guifg=#000000 guibg=#5f5f87 ctermfg=0 ctermbg=60 cterm=NONE
+hi Visual                    guibg=#5f5f87 ctermbg=60
+hi LineNr                    guifg=#666666 ctermfg=242
+hi Cursor                    guifg=#000000 guibg=#FFFFFF ctermfg=0 ctermbg=15
+hi CursorLine                guibg=#1c1c1c gui=NONE ctermbg=234 cterm=NONE
+hi CursorLineNr              guifg=#a9a8a8 gui=NONE ctermfg=248 cterm=NONE
+hi ColorColumn               guibg=#1c1c1c ctermbg=234
+hi! link CursorColumn ColorColumn
+hi VertSplit                 guifg=#444444 guibg=#121212 gui=NONE ctermfg=238 ctermbg=233 cterm=NONE
+hi SignColumn                guifg=#FFFFFF guibg=NONE ctermfg=15 ctermbg=NONE
+
+" StatusLine
+" Bold
+hi User1                     guifg=#eeeeee guibg=#606060 gui=bold ctermfg=255 ctermbg=241 cterm=bold
+" Yellow
+hi User2                     guifg=#FFAF00 guibg=#606060 gui=bold ctermfg=214 ctermbg=241 cterm=bold
+" Green
+hi User3                     guifg=#5fff00 guibg=#606060 gui=bold ctermfg=82 ctermbg=241 cterm=bold
+" Red
+hi User4                     guifg=#870000 guibg=#606060 gui=bold ctermfg=88 ctermbg=241 cterm=bold
+hi User5                     guifg=#e4e4e4 guibg=#606060 gui=bold ctermfg=254 ctermbg=241 cterm=bold
+hi User6                     guifg=#e4e4e4 guibg=#606060 gui=bold ctermfg=254 ctermbg=241 cterm=bold
+hi User7                     guifg=#e4e4e4 guibg=#606060 gui=bold ctermfg=254 ctermbg=241 cterm=bold
+hi User8                     guifg=#e4e4e4 guibg=#606060 gui=bold ctermfg=254 ctermbg=241 cterm=bold
+hi User9                     guifg=#e4e4e4 guibg=#606060 gui=bold ctermfg=254 ctermbg=241 cterm=bold
+hi StatusLine                guifg=#e4e4e4 guibg=#606060 gui=NONE ctermfg=254 ctermbg=241 cterm=NONE
+hi StatusLineNC              guifg=#585858 guibg=#303030 gui=NONE ctermfg=240 ctermbg=236 cterm=NONE
+
+" Folds
+" -----
+" line used for closed folds
+hi Folded                    guifg=#ffffff guibg=#444444 gui=NONE ctermfg=15 ctermbg=238 cterm=NONE
+hi! link FoldColumn SignColumn
+
+" Invisible Characters
+" ------------------
+hi NonText                   guifg=#767676 gui=NONE cterm=NONE ctermfg=243
+hi SpecialKey                guifg=#767676 gui=NONE cterm=NONE ctermfg=243
+
+" Misc
+" ----
+" directory names and other special names in listings
+hi Directory                 guifg=#87af5f gui=NONE ctermfg=107 cterm=NONE
+
+" Popup Menu
+" ----------
+" normal item in popup
+hi Pmenu                     guifg=#ffffff guibg=#444444 gui=NONE ctermfg=15 ctermbg=238 cterm=NONE
+" selected item in popup
+hi PmenuSel                  guifg=#000000 guibg=#87af5f gui=NONE ctermfg=0 ctermbg=107 cterm=NONE
+" scrollbar in popup
+hi PMenuSbar                 guibg=#5A647E gui=NONE ctermfg=15 ctermbg=60 cterm=NONE
+" thumb of the scrollbar in the popup
+hi PMenuThumb                guifg=#ffffff guibg=#a8a8a8 gui=NONE ctermfg=15 ctermbg=248 cterm=NONE
+
+" Code constructs
+" ---------------
+hi Comment                   guifg=#af875f ctermfg=137
+hi Todo                      guifg=#df5f5f guibg=NONE gui=bold ctermfg=167 ctermbg=NONE cterm=bold
+" hi Todo                      guifg=#000000 guibg=ffff00 gui=bold ctermfg=16 ctermbg=11 cterm=bold
+hi Constant                  guifg=#6D9CBE ctermfg=73
+hi Error                     guifg=#FFFFFF guibg=#990000 ctermfg=221 ctermbg=88
+hi WarningMsg                guifg=#800000 guibg=NONE ctermfg=1 ctermbg=NONE
+hi Identifier                guifg=#af5f5f gui=NONE ctermfg=221 cterm=NONE
+hi Keyword                   guifg=#af5f00 gui=NONE ctermfg=130 cterm=NONE
+hi Number                    guifg=#87af5f ctermfg=107
+hi Statement                 guifg=#af5f00 gui=NONE ctermfg=130 cterm=NONE
+hi String                    guifg=#87af5f ctermfg=107
+hi Title                     guifg=#FFFFFF ctermfg=15
+hi Type                      guifg=#df5f5f gui=NONE ctermfg=167 cterm=NONE
+hi PreProc                   guifg=#ff8700 ctermfg=208
+hi Special                   guifg=#005f00 ctermfg=22
+
+" Diffs
+" -----
+hi DiffAdd                   guifg=#e4e4e4 guibg=#519F50 ctermfg=254 ctermbg=22
+hi DiffDelete                guifg=#000000 guibg=#660000 gui=bold ctermfg=16 ctermbg=52 cterm=bold
+hi DiffChange                guifg=#FFFFFF guibg=#870087 ctermfg=15 ctermbg=90
+hi DiffText                  guifg=#FFFFFF guibg=#FF0000 gui=bold ctermfg=15 ctermbg=9 cterm=bold
+
+hi diffAdded                 guifg=#008700 ctermfg=28
+hi diffRemoved               guifg=#800000 ctermfg=1
+hi diffNewFile               guifg=#FFFFFF guibg=NONE gui=bold ctermfg=15 ctermbg=NONE cterm=bold
+hi diffFile                  guifg=#FFFFFF guibg=NONE gui=bold ctermfg=15 ctermbg=NONE cterm=bold
+
+
+" Ruby
+" ----
+hi rubyTodo                  guifg=#df5f5f guibg=NONE gui=bold ctermfg=167 ctermbg=NONE cterm=bold
+hi rubyClass                 guifg=#FFFFFF ctermfg=15
+hi rubyConstant              guifg=#df5f5f ctermfg=167
+hi rubyInterpolation         guifg=#FFFFFF ctermfg=15
+hi rubyBlockParameter        guifg=#dfdfff ctermfg=189
+hi rubyPseudoVariable        guifg=#ffdf5f ctermfg=221
+hi rubyStringDelimiter       guifg=#87af5f ctermfg=107
+hi rubyInstanceVariable      guifg=#dfdfff ctermfg=189
+hi rubyPredefinedConstant    guifg=#df5f5f ctermfg=167
+hi rubyLocalVariableOrMethod guifg=#dfdfff ctermfg=189
+
+" Python
+" ------
+hi pythonExceptions          guifg=#ffaf87 ctermfg=216
+hi pythonDoctest             guifg=#8787ff ctermfg=105
+hi pythonDoctestValue        guifg=#87d7af ctermfg=115
+
+" Mail
+" ----
+hi mailEmail                 guifg=#87af5f ctermfg=107 gui=italic cterm=underline
+hi mailHeaderKey             guifg=#ffdf5f ctermfg=221
+hi! link mailSubject mailHeaderKey
+
+" Spell
+" ----
+hi SpellBad                  guifg=#D70000 guibg=NONE gui=undercurl ctermfg=160 ctermbg=NONE cterm=underline
+hi SpellRare                 guifg=#df5f87 guibg=NONE gui=underline ctermfg=168 ctermbg=NONE cterm=underline
+hi SpellCap                  guifg=#dfdfff guibg=NONE gui=underline ctermfg=189 ctermbg=NONE cterm=underline
+hi SpellLocal                guifg=#00FFFF guibg=NONE gui=undercurl ctermfg=51 ctermbg=NONE cterm=underline
+hi MatchParen                guifg=#FFFFFF guibg=#005f5f ctermfg=15 ctermbg=23
+
+" XML
+" ---
+hi xmlTag                    guifg=#dfaf5f ctermfg=179
+hi xmlTagName                guifg=#dfaf5f ctermfg=179
+hi xmlEndTag                 guifg=#dfaf5f ctermfg=179
+
+" HTML
+" ----
+hi! link htmlTag              xmlTag
+hi! link htmlTagName          xmlTagName
+hi! link htmlEndTag           xmlEndTag
+
+hi checkbox guifg=#3a3a3a guibg=NONE gui=NONE ctermfg=237 ctermbg=NONE cterm=NONE
+hi checkboxDone guifg=#5fff00 guibg=NONE gui=BOLD ctermfg=82 ctermbg=NONE cterm=BOLD
+hi checkboxNotDone guifg=#005fdf guibg=NONE gui=BOLD ctermfg=26 ctermbg=NONE cterm=BOLD

.vim/scripts/rnutoggle.vim

@@ -0,0 +1,7 @@
+function! ToggleRelativeNumbers()
+				if &rnu == 1
+								set nornu
+				else
+								set rnu
+				endif
+endfunction

.vim/scripts/togglehighlight.vim

@@ -0,0 +1,7 @@
+function! ToggleHighlights()
+				if &hlsearch == 1 
+								set nohlsearch
+				else
+								set hlsearch
+				endif 
+endfunction

.vim/scripts/vimsurround-self.vim

@@ -0,0 +1,3 @@
+function! Vimsurround()
+				F"x<ESC>i'<ESC>f"x<ESC>i'
+endfunction

.vimrc

@@ -26,6 +26,7 @@ Plugin 'jacoborus/tender.vim' "Theme Tender
 " Plugin 'thoughtbot/vim-rspec' "RSpec Plugin
 Plugin 'MikeCoder/markdown-preview.vim' "Markdown preview
 Plugin 'lervag/vimtex' " LaTeX 
+Bundle 'ron89/thesaurus_query.vim'
 
 " All of your Plugins must be added before the following line
 call vundle#end()
@@ -112,3 +113,20 @@ set noeb vb t_vb= "Beeping can fuck right off
 set t_ut="" "Disabling Vim's 'Background Color Erase' option to mitigate the problem of wrong background colour rendering
 set breakindent "For better indentation
 autocmd BufWritePost config.h !sudo make clean install
+
+func! WordProcessor()
+  " movement changes
+  map j gj
+  map k gk
+  " formatting text
+  setlocal formatoptions=1
+  setlocal noexpandtab
+  setlocal wrap
+  setlocal linebreak
+  " spelling and thesaurus
+  setlocal spell spelllang=en_gb
+  set thesaurus+=/home/sophon/.vim/thesaurus/mthesaur.txt
+  " complete+=s makes autocompletion search the thesaurus
+  set complete+=s
+endfu
+com! WP call WordProcessor()